Return to configure.ac CVS log

Up to [DeepSpace6] / wget

Imported modified version of wget 1.9 beta, repackaged with autoconf2.5x/automake support and with new code for parsing urls with embedded IPv6 addresses.

dnl Template file for GNU Autoconf
dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.

dnl This program is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.

dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.

dnl You should have received a copy of the GNU General Public License
dnl along with this program; if not, write to the Free Software
dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.

dnl In addition, as a special exception, the Free Software Foundation
dnl gives permission to link the code of its release of Wget with the
dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
dnl that use the same license as the "OpenSSL" library), and distribute
dnl the linked executables.  You must obey the GNU General Public License
dnl in all respects for all of the code used other than "OpenSSL".  If you
dnl modify this file, you may extend this exception to your version of the
dnl file, but you are not obligated to do so.  If you do not wish to do
dnl so, delete this exception statement from your version.

dnl
dnl Process this file with autoconf to produce a configure script.
dnl
AC_PREREQ(2.57)              dnl Autoconf 2.57 or better is required
AC_INIT(wget, 1.9-beta, [wget@sunsite.dk])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_SRCDIR(src/version.c)
AM_INIT_AUTOMAKE(1.6)        dnl Automake 1.6 or better is required
AC_CONFIG_HEADER(config.h)
AM_GNU_GETTEXT_VERSION(0.12.1)

dnl
dnl We want these __before__ the checks, so the checks can modify their values.
dnl 
auto_cflags=false
if test -z "$CFLAGS" 
then
  CFLAGS=
  auto_cflags=true
fi 

dnl
dnl Enable maintainer mode
dnl
AM_MAINTAINER_MODE

dnl
dnl Get canonical host
dnl
AC_CANONICAL_HOST
AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os", [Define the host type.])

dnl
dnl Process features:
dnl
dnl 1) SOCKS 
dnl
AC_ARG_WITH(socks, AC_HELP_STRING([--with-socks],[use the socks library]))
if test "x${with_socks}" = "xyes"; then
  AC_DEFINE([HAVE_SOCKS], 1, [Define if the user wants SOCKS support.])
fi

dnl
dnl 2) SSL
dnl
AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl(=ssldir)],[enable SSL support (default=auto).]))

dnl
dnl 3) OPIE
dnl
AC_ARG_ENABLE(opie, AC_HELP_STRING([--disable-opie],[disable support for opie or s/key FTP login]))
dnl AM_CONDITIONAL(ENABLE_OPIE_SUPPORT, test "x${enable_opie}" = "xyes")
if test "x${enable_opie}" = "xyes"; then
  AC_DEFINE([USE_OPIE], 1, [Define if the user wants opie or s/key FTP login support.])
  AC_LIBOBJ(ftp-opie)
fi

dnl
dnl 4) HTTP Digest 
dnl
AC_ARG_ENABLE(digest, AC_HELP_STRING([--disable-digest],[disable support for HTTP digest authorization]))
if test "x${enable_digest}" = "xyes"; then
  AC_DEFINE([USE_DIGEST], 1, [Define if the user wants HTTP digest authorization support.])
fi

dnl
dnl 5) Debugging information
dnl
AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[disable support for debugging output]))
if test "x${enable_debug}" = "xyes"; then
  AC_DEFINE([DEBUG], 1, [Define if the user wants to build the package with debugging information.])
fi

dnl If we have to build wget with opie and/or HTTP digest support, then
dnl we need MD5 support.
case "${enable_opie}${enable_digest}" in
*yes*)	wget_need_md5="yes"
	;;
*)	wget_need_md5="no"
	;;
esac

dnl
dnl Handle AIX
dnl
AC_AIX

dnl
dnl Find the compiler and other programs
dnl
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_YACC
AC_ISC_POSIX
AC_PROG_RANLIB

dnl 
dnl Automatic de-ansi-fication
dnl
AM_C_PROTOTYPES


dnl
dnl If the user hasn't specified CFLAGS, then we setup the default CFLAGS 
dnl to use for wget sources.
dnl

WGET_CFLAGS=""

if test x"$auto_cflags" = xtrue; then
  if test -n "$GCC"; then
    # If compiler is gcc, then use some warning flags.
    # Should we use also -pipe here?
    WGET_CFLAGS="$WGET_CFLAGS -W -Wall -Wpointer-arith -Wno-implicit -Wstrict-prototypes -Wcast-qual -Wcast-align"
  fi
  if test "x${enable_debug}" = "xyes"; then
    WGET_CFLAGS="$WGET_CFLAGS -g"
  else
    # If compiler is gcc, then use -O2 and -finline-functions
    # else use os-specific flags or -O
    if test -n "$GCC"; then
      WGET_CFLAGS="$WGET_CFLAGS -O2 -finline-functions"
    else
      case "$host_os" in
        *hpux*)  
          WGET_CFLAGS="$WGET_CFLAGS +O3" ;;
        *ultrix* | *osf*) 
          WGET_CFLAGS="$WGET_CFLAGS -O -Olimit 2000" ;;
        *)       
          WGET_CFLAGS="$WGET_CFLAGS -O" ;;
      esac
    fi
  fi
fi 

dnl
dnl Configure our included libtool and make sure it's regenerated when needed
dnl
AC_PROG_LIBTOOL
AC_SUBST(LIBTOOL_DEPS)

dnl
dnl the AC_PROG_LIBTOOL/AC_SUBST(LIBTOOL_DEPS) couple would be overkill here...
dnl
dnl AC_PATH_PROG(LIBTOOL, [libtool], [no])
dnl AC_ARG_VAR(LIBTOOL, [GNU Libtool program.])
dnl if test "x${LIBTOOL}" = "xno"; then
dnl 	AC_MSG_ERROR([Cannot find libtool, which is needed in order to compile GNU wget.])
dnl fi

dnl
dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
dnl Might also be erelevant for DJGPP.
dnl
case "$host_os" in
  *win32) exeext='.exe';;
  *) exeext='';;
esac
AC_SUBST(exeext)

dnl
dnl Checks for header files.
dnl
AC_HEADER_STDC
AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h langinfo.h libintl.h limits.h]) 
AC_CHECK_HEADERS([locale.h malloc.h netdb.h netinet/in.h pwd.h setjmp.h]) 
AC_CHECK_HEADERS([signal.h stdarg.h stddef.h strings.h sys/ioctl.h sys/param.h])
AC_CHECK_HEADERS([sys/select.h sys/socket.h sys/time.h sys/utime.h])
AC_CHECK_HEADERS([sys/utsname.h termios.h unistd.h utime.h])

dnl
dnl Checks for alloca.h header and alloca function.
dnl
AC_FUNC_ALLOCA
if test -n "$ALLOCA" 
then
  AC_LIBOBJ(alloca)
fi

dnl
dnl Checks for typedefs, structures, and compiler characteristics.
dnl
AC_HEADER_STAT
AC_C_CONST
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
AC_STRUCT_TM
AC_C_VOLATILE
dnl #### This generates a warning.  What do I do to shut it up?
AC_C_BIGENDIAN
dnl Check size of long.
AC_CHECK_SIZEOF([long])
AC_CHECK_SIZEOF([long long])

dnl
dnl Check for struct utimbuf: this must be done __after__ the check for utime.h
dnl
WGET_STRUCT_UTIMBUF(AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define if the system supports struct utimbuf.]))

dnl
dnl Checks for library functions.
dnl
AM_GNU_GETTEXT
AC_FUNC_FORK
AC_PROG_GCC_TRADITIONAL
AC_FUNC_MMAP
AC_FUNC_SELECT_ARGTYPES
AC_TYPE_SIGNAL
AC_FUNC_UTIME_NULL
AC_FUNC_VPRINTF
AC_CHECK_FUNC([getopt_long], , AC_LIBOBJ(getopt))
AC_CHECK_FUNCS([access __argz_count __argz_next __argz_stringify alarm atexit]) 
AC_CHECK_FUNCS([ftruncate getcwd gettimeofday isatty localtime_r memchr memmove]) 
AC_CHECK_FUNCS([mempcpy memset mkdir munmap nl_langinfo select setlocale signal])
AC_CHECK_FUNCS([sigsetjmp snprintf socket stpcpy strcasecmp strchr strcspn strdup])
AC_CHECK_FUNCS([strerror strncasecmp strpbrk strptime strrchr strstr strtol strtoul])
AC_CHECK_FUNCS([symlink uname usleep utime vsnprintf]) 
dnl
dnl We should use:
dnl
dnl AC_FUNC_LSTAT
dnl AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
dnl AC_FUNC_MALLOC
dnl AC_FUNC_MEMCMP
dnl AC_FUNC_MKTIME
dnl AC_FUNC_REALLOC
dnl AC_FUNC_STAT
dnl
dnl instead of the following statement, but to do so we would need 
dnl an internal replacement for each of these functions :-P
dnl
AC_CHECK_FUNCS([lstat malloc memcmp mktime realloc stat])

dnl
dnl Checks for libraries.
dnl

dnl On Solaris, -lnsl is needed to use gethostbyname.  On "NCR MP-RAS
dnl 3.0", however, gethostbyname is in libc, but -lnsl is still needed
dnl to use -lsocket, as well as for functions such as inet_ntoa.  We
dnl look for such known offenders and if one of them is not found, we
dnl check if -lnsl is needed.

wget_check_in_nsl=NONE
AC_CHECK_FUNCS(gethostbyname, [], [
  wget_check_in_nsl=gethostbyname
])
AC_CHECK_FUNCS(inet_ntoa, [], [
  wget_check_in_nsl=inet_ntoa
])
if test $wget_check_in_nsl != NONE; then
  AC_CHECK_LIB(nsl, $wget_check_in_nsl)
fi

AC_CHECK_LIB(socket, socket)

dnl #### This appears to be deficient with later versions of SOCKS.
if test "x${with_socks}" = xyes
then
  AC_CHECK_LIB(resolv, main)
  AC_CHECK_LIB(socks, Rconnect)
fi


dnl $with_ssl can be one of:
dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
dnl  - "yes", meaning link with SSL or bail out.
dnl  - "no", meaning don't link with SSL.
dnl  - anything else, meaning use that as the SSL root, and bail out
dnl    if it fails.

if test x"${with_ssl}" = x; then
  dnl Canonicalize unspecified with-ssl setting to "auto".  This
  dnl implements the "auto-detect by default" feature.  If you want to
  dnl change this to "ignore SSL by default", change "auto" to "no".
  with_ssl=auto
fi

dnl Detection of OpenSSL is much hairier than the detection of other
dnl libraries because OpenSSL can be compiled as a third-party
dnl library, which means it will not be found without additional
dnl linker magic.  It would be really nice to rework this check into
dnl an AC_DEFUN so that we can reuse it for other third-party
dnl libraries.

if test x"$with_ssl" != x"no"; then

  wget_force_ssl=no
  if test x"$with_ssl" = x"yes"; then
    wget_force_ssl=yes
  fi

  if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
    dnl OpenSSL's root was not specified, so we have to guess.  First
    dnl try the system default location, then "/usr/local/ssl" (where
    dnl OpenSSL installs by default), then "/usr/local" (traditional
    dnl choice for installation root), then "/opt".
    ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
  else
    dnl Root has been specified by the user.
    ssl_all_roots=$with_ssl
    wget_force_ssl=yes
  fi

  wget_save_CC=$CC
  wget_save_LIBS=$LIBS
  wget_save_LDFLAGS=$LDFLAGS
  wget_save_CPPFLAGS=$CPPFLAGS

  dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
  dnl without having to know how the linker handles it.
  CC="$SHELL $LIBTOOL $CC"

  dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
  dnl shared library doesn't record its dependency on libdl, so we
  dnl need to check for it ourselves so we won't fail to link due to a
  dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
  dnl shl_load().
  AC_CHECK_LIB(dl,dlopen)
  AC_CHECK_LIB(dl,shl_load)

  ssl_success=no

  dnl Now try to find SSL libraries in each of the likely SSL roots.
  for ssl_root in $ssl_all_roots
  do
    if test x"$ssl_root" = x"system-default"; then
      dnl Try the default include and library locations.
      SSL_INCLUDES=
    else
      dnl Try this specific root.
      SSL_INCLUDES=-I$ssl_root/include
      dnl It's OK to use -R directly because libtool will
      dnl interpret it for us.
      LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
    fi

    AC_MSG_NOTICE([Looking for SSL libraries in $ssl_root])

    dnl Check whether the compiler can find the include files.  On
    dnl some systems Gcc finds libraries in /usr/local/lib, but fails
    dnl to find the includes in /usr/local/include.

    ssl_found_includes=no
    CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"

    AC_MSG_CHECKING([for includes])

    AC_TRY_CPP([#include <openssl/ssl.h>
#include <openssl/rsa.h>
],
      AC_MSG_RESULT([found]); ssl_found_includes=yes,
      AC_MSG_RESULT([not found])
    )

    if test x"$ssl_found_includes" = xno; then
      continue
    fi

    ssl_link_failure=no

    dnl Make sure that the checks don't run afoul of the cache.  It
    dnl would be nicer to temporarily turn off the cache, but
    dnl apparently Autoconf doesn't allow that.

    unset ac_cv_lib_crypto_RSA_new
    unset ac_cv_lib_ssl_SSL_new

    dnl These checks need to be in this order, or you'll get a link
    dnl failure if you use a static libcrypto.a and libssl.a rather
    dnl than shared libraries.

    AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
    AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)

    if test x"$ssl_link_failure" = xyes; then
      dnl One or both libs failed to link.
      continue
    fi

    dnl The libraries link.  But we still need to check if the program
    dnl linked with those libraries under these settings with run.  On
    dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
    dnl linking line, but fails to add -R/usr/local/lib, thus creating
    dnl executables that link, but fail to run.

    dnl If we are cross-compiling, just assume that working linkage
    dnl implies working executable.

    ssl_run_failure=no

    AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
    AC_TRY_RUN([
int RSA_new();
int SSL_new();
main(){return 0;}
],
      AC_MSG_RESULT(yes),
      AC_MSG_RESULT(no); ssl_run_failure=yes,
      AC_MSG_RESULT(cross)
    )

    if test x"$ssl_run_failure" = xno; then
      ssl_success=yes
      break
    fi
  done

  if test x"$ssl_success" = xyes; then
    AC_MSG_NOTICE([Compiling in support for SSL in $ssl_root])
    AC_DEFINE([HAVE_SSL], 1, [Define if we have SSL support.])
    AC_SUBST(SSL_INCLUDES)
    AC_LIBOBJ(gen_sslfunc)
  else
    LDFLAGS=$wget_save_LDFLAGS
    LIBS=$wget_save_LIBS

    dnl If linking with SSL was forced rather than auto-detected, then
    dnl bail out if SSL failed.
    if test x"$wget_force_ssl" = xyes; then
      exec >&2
      echo "ERROR: Failed to find OpenSSL libraries."
      exit 2
    fi
  fi

  dnl Restore the compiler setting.
  CC=$wget_save_CC

  dnl Restore the CPPFLAGS.  Do this regardless of whether linking
  dnl with SSL succeeded -- SSL includes will be handled using
  dnl @SSL_INCLUDES@.
  CPPFLAGS=$wget_save_CPPFLAGS
fi


dnl
dnl Find an md5 implementation.
dnl

if test x"${wget_need_md5}" = xyes
then
  found_md5=no
  use_builtin_md5=no

  dnl Check for the system MD5 library on Solaris.  We don't check for
  dnl something simple like "MD5Update" because there are a number of
  dnl MD5 implementations that use that name.  md5_calc is, hopefully,
  dnl specific to the Solaris MD5 library.
  if test x"$found_md5" = xno; then
    AC_CHECK_LIB(md5, md5_calc, [
      AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define if we have OpenSSL MD5 support.])
      LIBS="-lmd5 $LIBS"
      found_md5=yes
    ])
  fi

  dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
  dnl implementation.
  if test x"$found_md5" = xno; then
    if test x"$ssl_success" = xyes; then
      AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define if we have OpenSSL MD5 support.])
      found_md5=yes
    fi
  fi

  dnl If none of the above worked, use the one we ship with Wget.
  if test x"$found_md5" = xno; then
    AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define if we have builtin MD5 support.])
    use_builtin_md5=no
    found_md5=yes
  fi
fi

AM_CONDITIONAL(NEED_MD5_SUPPORT, test x"$use_builtin_md5" = xyes)

if test x"$found_md5" = xyes; then
  AC_DEFINE([HAVE_MD5], 1, [Define if we have MD5 support.])
fi

dnl
dnl Find perl and pod2man
dnl
AC_PATH_PROGS([PERL], [perl5 perl], [no])
AC_ARG_VAR([PERL], [Perl interpreter.])
AC_PATH_PROG([POD2MAN], [pod2man], [no])
AC_ARG_VAR([POD2MAN], [pod2man program.])
AM_CONDITIONAL(HAVE_POD2MAN, test "x${POD2MAN}" != xno)

dnl
dnl Create output
dnl
AC_SUBST(WGET_CFLAGS)
AC_SUBST(ac_aux_dir)
AC_CONFIG_FILES([Makefile config/Makefile doc/Makefile doc/texi2pod.pl intl/Makefile src/Makefile util/Makefile util/rmold.pl util/wget.spec po/Makefile.in windows/Makefile])
AC_OUTPUT